pkgbuilds/terminus-font-patched/PKGBUILD

#
# Original maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Kristoffer Fossgård <kfs1@online.no>
# Contributor: clonejo <clonejo@shakik.de>
# Contributor: Daniel Micay <danielmicay@gmail.com>
#
# This is the modified version of the original archlinux terminus-font
# to incorporate most of the patches that I find really useful:
# br1 just for the sake of it
# dv1 because handwritten versions in a computer font suck
# ij1 because и ≠ u, need a way to tell them apart
# ll2 because ilI1
# td1 because tilda should be in the middle
#
# boxdraw patch added to prevent box lines from being thick in terminals with bold font

pkgname=terminus-font-patched
_pkgname=terminus-font
pkgver=4.49.1
pkgrel=1

pkgdesc='Monospace bitmap font (for X11 and console)'
url='http://terminus-font.sourceforge.net/'
arch=('any')
license=('GPL2' 'custom:OFL')
makedepends=('xorg-bdftopcf' 'python')
provides=($_pkgname)
conflicts=($_pkgname)
install='terminus-font-patched.install'
source=("http://downloads.sourceforge.net/project/$_pkgname/$_pkgname-${pkgver%.1}/$_pkgname-$pkgver.tar.gz"
        fix-75-yes-terminus.patch)
sha256sums=('d961c1b781627bf417f9b340693d64fc219e0113ad3a3af1a3424c7aa373ef79'
            'ddd86485cf6d54e020e36f1c38c56e8b21b57c23a5d76250e15c1d16fed9caa5')

prepare() {
  cd "terminus-font-$pkgver"
  patch -p1 <"$srcdir"/fix-75-yes-terminus.patch
}

build() {
  cd "$_pkgname-$pkgver"

  patch -p0 -i alt/br1.diff
  patch -p0 -i alt/dv1.diff
  patch -p0 -i alt/ij1.diff
  patch -p0 -i alt/ll2.diff
  patch -p0 -i alt/td1.diff

  ./configure \
    --prefix=/usr \
    --x11dir=/usr/share/fonts/misc \
    --otbdir=/usr/share/fonts/misc \
    --psfdir=/usr/share/kbd/consolefonts
  make all otb
}

package() {
  make -C "$_pkgname-$pkgver" DESTDIR="$pkgdir" install install-otb

  install -Dm644 "$srcdir/$_pkgname-$pkgver/75-yes-terminus.conf" \
    "$pkgdir/etc/fonts/conf.avail/75-yes-terminus.conf"
  install -Dm644 "$srcdir/$_pkgname-$pkgver/OFL.TXT" \
    "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
  install -d "$pkgdir/etc/fonts/conf.d"

  cd "$pkgdir/etc/fonts/conf.d"
  ln -s ../conf.avail/75-yes-terminus.conf .
}

# getver: terminus-font.sf.net
# vim:set ts=2 sw=2 et: