pkgbuilds/terminus-font-patched/PKGBUILD

#
# Original maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Kristoffer Fossgård <kfs1@online.no>
# Contributor: clonejo <clonejo@shakik.de>
# Contributor: Daniel Micay <danielmicay@gmail.com>
#
# This is the modified version of the original archlinux terminus-font
# to incorporate most of the patches that I find really useful:
# br1 just for the sake of it
# dv1 because handwritten versions in a computer font suck
# ij1 because и ≠ u, need a way to tell them apart
# ll2 because ilI1
# td1 because tilda should be in the middle
#
# boxdraw patch added to prevent box lines from being thick in terminals with bold font

pkgname=terminus-font-patched
_pkgname=terminus-font
pkgver=4.47
pkgrel=3
pkgdesc='Monospace bitmap font (for X11 and console)'
arch=('any')
url='http://sourceforge.net/projects/terminus-font/'
license=('GPL2' 'custom:OFL')
makedepends=('xorg-bdftopcf' 'fontconfig' 'xorg-mkfontscale' 'xorg-mkfontdir' 'python3')
optdepends=('xorg-fonts-alias')
depends=('fontconfig' 'xorg-fonts-encodings' 'xorg-font-utils')
install='terminus-font-patched.install'
source=("http://downloads.sourceforge.net/project/$_pkgname/$_pkgname-$pkgver/$_pkgname-$pkgver.tar.gz"
        'boxdraw.diff')
provides=($_pkgname)
conflicts=($_pkgname)
sha256sums=('0f1b205888e4e26a94878f746b8566a65c3e3742b33cf9a4e6517646d5651297'
            'e247c997ef9dc135cdd3ed84b2cbdeb9c47b6bb9f951dff9aa9cb1661f30b0d6')

prepare() {
  chmod +x "$_pkgname-$pkgver/configure"
}

build() {
  cd "$_pkgname-$pkgver"
  patch -p0 -i alt/br1.diff
  patch -p0 -i alt/dv1.diff
  patch -p0 -i alt/ij1.diff
  patch -p0 -i alt/ll2.diff
  patch -p0 -i alt/td1.diff
  patch -p1 -i ../boxdraw.diff
  ./configure --prefix=/usr --x11dir=/usr/share/fonts/misc \
    --psfdir=/usr/share/kbd/consolefonts
  make
}

package() {
  make -C "$_pkgname-$pkgver" DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/$_pkgname-$pkgver/75-yes-terminus.conf" \
    "$pkgdir/etc/fonts/conf.avail/75-yes-terminus.conf"
  install -Dm644 "$srcdir/$_pkgname-$pkgver/OFL.TXT" \
    "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
  install -d "$pkgdir/etc/fonts/conf.d"

  cd "$pkgdir/etc/fonts/conf.d"
  ln -s ../conf.avail/75-yes-terminus.conf .
}

# getver: terminus-font.sf.net
# vim:set ts=2 sw=2 et: