# Original maintainer: Andreas Radke <andyrtr@archlinux.org>
# Original maintainer: Jan de Groot <jgc@archlinux.org>
#
# This is a modified version of xkeyboard-config to provide emulation for ducky
# mini fn key layout that I got used to very much
#
# they don't make those keyboards any more :(

_pkgname=xkeyboard-config
pkgname=xkeyboard-config-ducky
pkgver=2.26
pkgrel=3
pkgdesc="X keyboard configuration files"
arch=(any)
license=('custom')
url="https://www.freedesktop.org/wiki/Software/XKeyboardConfig"
makedepends=('intltool' 'xorg-xkbcomp' 'libxslt')
provides=('xkbdata' "${_pkgname}")
replaces=('xkbdata' "${_pkgname}")
conflicts=('xkbdata' "${_pkgname}")
source=(https://xorg.freedesktop.org/archive/individual/data/${_pkgname}/${_pkgname}-${pkgver}.tar.bz2
        pt-layout.patch
        ducky_mini
        ru.patch
        us.patch)
sha512sums=('5c8a31f7a6ad5daed8a3fceb56230b2e2fc04a25f52a43b3b4ea81e4a6ab15c52869f749c4b747d855cd4b618c04bcbb40e85dec7eab31fbe3bd45e8c9b755ef'
            '98c8b47e9a36ba3f130454fdd68c508f54b78eb65ddb071ca85bdcc3b324699e51155e3fc425ccae98350bb6430fea4771c0338024c1e06063a54b879bb707db'
            'ac79eb7fb16f517cf1178bcbfe83f708741feb950ee1e1c92fcea2b1e10ceae6d9f90ad860440f64da6759c843bcc10f4ac2479d323c450aeaf323bf37722257'
            '854c52d168837a5c72559498d10dff7843275323c4082d1c741c832d068108be3a51e823c98a27ea47c5fe4f335499fdbcaa3698117740ef24c07c41161ad59b'
            '7d9c692980c77a3b0658a5dd707ecdcd1e3fe47c2958f539f1f81dd04d5f204f779569d6b880c3f12872397d6171b2ec2caab9a4e79461c9f5828ca1c45acb08')

build() {
  cd ${_pkgname}-${pkgver}
  cp -v ${srcdir}/ducky_mini symbols
  patch -p1 < ${srcdir}/ru.patch
  patch -p1 < ${srcdir}/us.patch
  ./configure --prefix=/usr \
      --with-xkb-base=/usr/share/X11/xkb \
      --with-xkb-rules-symlink=xorg \
      --enable-compat-rules=yes
  make
 }

 package() {
  cd ${_pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  rm -f "${pkgdir}/usr/share/X11/xkb/compiled"

  install -m755 -d "${pkgdir}/var/lib/xkb"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}