actually, name that package differently, so a random update does not break things

xkeyboard-config-ducky/PKGBUILD

@@ -0,0 +1,52 @@
+#
+# Original maintainer: Andreas Radke <andyrtr@archlinux.org>
+# Original maintainer: Jan de Groot <jgc@archlinux.org>
+#
+# This is a modified version of xkeyboard-config to provide emulation for ducky
+# mini fn key layout that I got used to very much
+#
+# they don't make those keyboards any more :(
+
+_pkgname=xkeyboard-config
+pkgname=xkeyboard-config-ducky
+pkgver=2.22
+pkgrel=1
+pkgdesc="X keyboard configuration files"
+arch=(any)
+license=('custom')
+url="https://www.freedesktop.org/wiki/Software/XKeyboardConfig"
+makedepends=('intltool' 'xorg-xkbcomp' 'libxslt')
+provides=('xkbdata' "${_pkgname}")
+replaces=('xkbdata' "${_pkgname}")
+conflicts=('xkbdata' "${_pkgname}")
+source=("https://xorg.freedesktop.org/archive/individual/data/${_pkgname}/${_pkgname}-${pkgver}.tar.bz2"
+        'ducky_mini'
+        'ru.patch'
+        'us.patch')
+sha256sums=('deaec9989fbc443358b43864437b7b6d39caff07890a4a8055105ce9fcaa59bd'
+            '8068381fb15735e60e636ab1b42f99f98e7112be8e9bd03f436688eb2a19ea80'
+            '3f62c3684339c3fb4c51a33c485685f881d20013971d114774ece3b613001832'
+            '215471b50a3c9544dd2e185cc34dd60bec3be8c54c12ed66723f81846f73eb38')
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  cp -v ${srcdir}/ducky_mini symbols
+  patch -p1 < ${srcdir}/ru.patch
+  patch -p1 < ${srcdir}/us.patch
+  ./configure --prefix=/usr \
+      --with-xkb-base=/usr/share/X11/xkb \
+      --with-xkb-rules-symlink=xorg \
+      --enable-compat-rules=yes
+  make
+ }
+
+ package() {
+  cd ${_pkgname}-${pkgver}
+
+  make DESTDIR="${pkgdir}" install
+  rm -f "${pkgdir}/usr/share/X11/xkb/compiled"
+
+  install -m755 -d "${pkgdir}/var/lib/xkb"
+  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
+}