xkeyboard-config-ducky, mako

mako/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Brett Cornwall <ainola@archlinux.org>
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+# Contributor: Drew DeVault
+
+pkgname=mako
+pkgver=1.6
+pkgrel=4
+license=('MIT')
+pkgdesc='Lightweight notification daemon for Wayland'
+makedepends=("meson" "scdoc" "systemd" "wayland-protocols")
+depends=(
+	"gdk-pixbuf2"
+	"pango"
+	"systemd-libs"
+	"wayland"
+)
+optdepends=("jq: support for 'makoctl menu'")
+arch=("x86_64")
+url='https://mako-project.org'
+options=(debug)
+source=(
+	"$pkgname-$pkgver.tar.gz::https://github.com/emersion/mako/releases/download/v$pkgver/mako-$pkgver.tar.gz"
+	"systemd-dbus-activation.patch"
+	"https://patch-diff.githubusercontent.com/raw/emersion/mako/pull/393.patch"
+)
+sha256sums=('9f43cba9e1b43c69be8c9e4a79c358b3cd22153ca3ffb8bf0ee7aa30c59b2fc2'
+            '4579a2673dcf2114779e10ed52d771f3930c2192e8e35d3e145163d9e0b45c20'
+            'SKIP')
+
+prepare() {
+	patch -Np1 -i "$srcdir/systemd-dbus-activation.patch" -d "$pkgname-$pkgver"
+	patch -Np1 -i "$srcdir/393.patch" -d "$pkgname-$pkgver"
+}
+
+build() {
+	arch-meson -Dzsh-completions=true -Dsd-bus-provider=libsystemd "$pkgname-$pkgver" build
+	ninja -C build
+}
+
+package() {
+	DESTDIR="$pkgdir" ninja -C build install
+	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" "$pkgname-$pkgver/LICENSE"
+	install -Dm644 -t "$pkgdir/usr/lib/systemd/user/" "$pkgname-$pkgver/contrib/systemd/mako.service"
+}