50 lines
1.5 KiB
Text
50 lines
1.5 KiB
Text
|
# $Id: PKGBUILD 133580 2015-05-16 16:23:32Z anatolik $
|
||
|
|
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
||
|
|
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
|
||
|
|
# Contributor: Sébastien Luttringer
|
||
|
|
# Contributor: xduugu
|
||
|
|
# Contributor: Ronald van Haren <ronald.archlinux.org>
|
||
|
|
# Contributor: Vesa Kaihlavirta
|
||
|
|
|
||
|
|
pkgname=awesome
|
||
|
|
pkgver=3.5.6
|
||
|
|
pkgrel=2
|
||
|
|
pkgdesc='Highly configurable framework window manager'
|
||
|
|
arch=('i686' 'x86_64')
|
||
|
|
url='http://awesome.naquadah.org/'
|
||
|
|
license=('GPL2')
|
||
|
|
depends=('cairo' 'dbus' 'gdk-pixbuf2' 'imlib2' 'libxdg-basedir' 'lua' 'lua-lgi'
|
||
|
|
'pango' 'startup-notification' 'xcb-util-cursor' 'xcb-util-keysyms'
|
||
|
|
'xcb-util-wm' 'xorg-xmessage')
|
||
|
|
makedepends=('asciidoc' 'cmake' 'docbook-xsl' 'doxygen' 'imagemagick' 'ldoc' 'xmlto')
|
||
|
|
optdepends=('rlwrap: readline support for awesome-client'
|
||
|
|
'dex: autostart your desktop files'
|
||
|
|
'vicious: widgets for the Awesome window manager')
|
||
|
|
provides=('notification-daemon')
|
||
|
|
backup=('etc/xdg/awesome/rc.lua')
|
||
|
|
source=($url/download/$pkgname-$pkgver.tar.xz)
|
||
|
|
md5sums=('db1c31de752ab8e5f7aaa338718202af')
|
||
|
|
|
||
|
|
prepare() {
|
||
|
|
mkdir -p build
|
||
|
|
patch -p0 < ../vte-hints-fix.diff
|
||
|
|
}
|
||
|
|
|
||
|
|
build() {
|
||
|
|
cd build
|
||
|
|
cmake ../$pkgname-$pkgver \
|
||
|
|
-DCMAKE_BUILD_TYPE=RELEASE \
|
||
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
||
|
|
-DSYSCONFDIR=/etc \
|
||
|
|
-DLUA_LIBRARY=/usr/lib/liblua.so.5.3
|
||
|
|
make
|
||
|
|
}
|
||
|
|
|
||
|
|
package() {
|
||
|
|
cd build
|
||
|
|
make DESTDIR="$pkgdir" install
|
||
|
|
|
||
|
|
install -Dm644 "$srcdir"/$pkgname-$pkgver/awesome.desktop \
|
||
|
|
"$pkgdir/usr/share/xsessions/awesome.desktop"
|
||
|
|
}
|