78 lines
2.6 KiB
Text
78 lines
2.6 KiB
Text
|
# $Id$
|
||
|
|
# Original Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
|
||
|
|
# Contributor: Gaetan Bisson <bisson@archlinux.org>
|
||
|
|
# Contributor: Alexander Fehr <pizzapunk gmail com>
|
||
|
|
# Contributor: William Rea <sillywilly@gmail.com>
|
||
|
|
|
||
|
|
pkgname=audacious-plugins
|
||
|
|
pkgver=3.9
|
||
|
|
pkgrel=2
|
||
|
|
pkgdesc="Plugins for Audacious"
|
||
|
|
arch=('x86_64')
|
||
|
|
url="http://audacious-media-player.org/"
|
||
|
|
license=('BSD' 'GPL')
|
||
|
|
|
||
|
|
makedepends=("audacious>=$pkgver" 'qt5-multimedia'
|
||
|
|
'glib2' 'python' # for gdbus-codegen
|
||
|
|
'alsa-lib' 'pulseaudio' 'jack2' 'lame' 'libvorbis' 'flac'
|
||
|
|
'mpg123' 'faad2' 'ffmpeg' 'libmodplug' 'fluidsynth' 'libcdio-paranoia' 'libsidplayfp' 'wavpack'
|
||
|
|
'dbus-glib' 'libsamplerate' 'libnotify' 'lirc' 'curl' 'libmtp'
|
||
|
|
'neon' 'libmms' 'libcue')
|
||
|
|
|
||
|
|
optdepends=('alsa-lib: Advanced Linux Sound Arch. output'
|
||
|
|
'pulseaudio: PulseAudio output'
|
||
|
|
'jack2: Jack Audio Connection Kit output'
|
||
|
|
'lame: FileWriter MP3 output'
|
||
|
|
'libvorbis: Vorbis input, FileWriter Vorbis output'
|
||
|
|
'flac: FLAC input, FileWriter FLAC output'
|
||
|
|
|
||
|
|
'mpg123: MP3 input'
|
||
|
|
'faad2: AAC input'
|
||
|
|
'ffmpeg: ffaudio input'
|
||
|
|
'libmodplug: modplug input'
|
||
|
|
'fluidsynth: MIDI FluidSynth backend input'
|
||
|
|
'libcdio-paranoia: CD Digital Audio input'
|
||
|
|
'libsidplayfp: Commodore 64 audio input'
|
||
|
|
'wavpack: WavPack input'
|
||
|
|
|
||
|
|
'dbus-glib: Gnome Shortcuts Plugin'
|
||
|
|
'libsamplerate: Speed and Pitch Plugin'
|
||
|
|
'libnotify: libnotify OSD'
|
||
|
|
'lirc: LIRC'
|
||
|
|
'curl: AudioScrobbler Client'
|
||
|
|
'libmtp: Upload to MTP device'
|
||
|
|
|
||
|
|
'neon: neon-based http transport'
|
||
|
|
'libmms: libmms-based mms transport'
|
||
|
|
'libcue: CUE playlist format'
|
||
|
|
'qt5-multimedia: qtaudio support')
|
||
|
|
|
||
|
|
source=(http://distfiles.audacious-media-player.org/$pkgname-$pkgver.tar.bz2)
|
||
|
|
sha256sums=('8bf7f21089cb3406968cc9c71307774aee7100ec4607f28f63cf5690d5c927b8')
|
||
|
|
|
||
|
|
prepare() {
|
||
|
|
cd "$srcdir/$pkgname-$pkgver"/src/qtui
|
||
|
|
|
||
|
|
# /usr/include/qt/QtGui/qstatictext.h:70:18: note: no known conversion for argument 1 from ‘QString’ to ‘const QStaticText&’
|
||
|
|
# Failed to compile info_bar.cc (plugin)!
|
||
|
|
sed -i 's|d.title = metrics.elidedText|d.title.text() = metrics.elidedText|' info_bar.cc
|
||
|
|
}
|
||
|
|
|
||
|
|
build() {
|
||
|
|
cd "$srcdir/$pkgname-$pkgver"
|
||
|
|
|
||
|
|
./configure \
|
||
|
|
--prefix=/usr \
|
||
|
|
--enable-qt \
|
||
|
|
--enable-amidiplug
|
||
|
|
make
|
||
|
|
}
|
||
|
|
|
||
|
|
package() {
|
||
|
|
cd "$srcdir/$pkgname-$pkgver"
|
||
|
|
make DESTDIR="$pkgdir" install
|
||
|
|
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
||
|
|
}
|
||
|
|
|
||
|
|
# vim:set ts=2 sw=2 et:
|